Add the -Dtcmalloc option.

CMakeLists.txt

@@ -46,6 +46,12 @@ ROOT_CHECK_OUT_OF_SOURCE_BUILD()
 include(SearchInstalledSoftware)
 ROOT_SHOW_OPTIONS()
 
+#---Here we add tcmalloc to the linker flags if needed------------------------------------------
+if (TCMALLOC_FOUND)
+  set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -ltcmalloc")
+  set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -ltcmalloc")
+endif()
+
 #---Populate the configure arguments returned by 'root-config --config'-------------------------
 get_cmake_property(variables CACHE_VARIABLES)
 foreach(var ${variables})

cmake/modules/Findtcmalloc.cmake

+# - Locate tcmalloc library
+# Defines:
+#
+#  TCMALLOC_FOUND
+#  TCMALLOC_INCLUDE_DIR
+#  TCMALLOC_INCLUDE_DIRS (not cached)
+#  TCMALLOC_tcmalloc_LIBRARY
+#  TCMALLOC_profiler_LIBRARY
+#  TCMALLOC_LIBRARIES (not cached)
+#  TCMALLOC_LIBRARY_DIRS (not cached)
+#  PPROF_EXECUTABLE
+
+find_path(TCMALLOC_INCLUDE_DIR google/tcmalloc.h)
+foreach(component tcmalloc profiler)
+  find_library(TCMALLOC_${component}_LIBRARY NAMES ${component})
+  mark_as_advanced(TCMALLOC_${component}_LIBRARY)
+endforeach()
+
+find_program(PPROF_EXECUTABLE NAMES pprof
+             HINTS ${TCMALLOC_INCLUDE_DIR}/../bin)
+
+set(TCMALLOC_INCLUDE_DIRS ${TCMALLOC_INCLUDE_DIR})
+set(TCMALLOC_LIBRARIES ${TCMALLOC_tcmalloc_LIBRARY} ${TCMALLOC_profiler_LIBRARY})
+
+# handle the QUIETLY and REQUIRED arguments and set TCMALLOC_FOUND to TRUE if
+# all listed variables are TRUE
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(tcmalloc DEFAULT_MSG TCMALLOC_INCLUDE_DIR TCMALLOC_LIBRARIES)
+
+mark_as_advanced(TCMALLOC_FOUND TCMALLOC_INCLUDE_DIR PPROF_EXECUTABLE)
+
+if(TCMALLOC_tcmalloc_LIBRARY)
+  get_filename_component(TCMALLOC_LIBRARY_DIRS ${TCMALLOC_tcmalloc_LIBRARY} PATH)
+elseif(TCMALLOC_profiler_LIBRARY)
+  get_filename_component(TCMALLOC_LIBRARY_DIRS ${TCMALLOC_profiler_LIBRARY} PATH)
+endif()

cmake/modules/RootBuildOptions.cmake

@@ -163,6 +163,7 @@ ROOT_BUILD_OPTION(srp ON "SRP support, requires SRP source tree")
 ROOT_BUILD_OPTION(ssl ON "SSL encryption support, requires openssl")
 ROOT_BUILD_OPTION(gnuinstall OFF "Perform installation following the GNU guidelines")
 ROOT_BUILD_OPTION(table ${table_defvalue} "Build libTable contrib library")
+ROOT_BUILD_OPTION(tcmalloc OFF "Using the tcmalloc allocator")
 ROOT_BUILD_OPTION(thread ON "Using thread library (cannot be disabled)")
 ROOT_BUILD_OPTION(tmva ON "Build TMVA multi variate analysis library")
 ROOT_BUILD_OPTION(unuran ${unuran_defvalue} "UNURAN - package for generating non-uniform random numbers")

cmake/modules/SearchInstalledSoftware.cmake

@@ -843,6 +843,16 @@ if(vc)
   endif()
 endif()
 
+#---Check for TCMalloc---------------------------------------------------------------
+
+if (tcmalloc)
+  message(STATUS "Looking for tcmalloc")
+  find_package(tcmalloc)
+  if(NOT TCMALLOC_FOUND)
+    message(STATUS "TCMalloc not found.")
+  endif()
+endif()
+
 #---Report non implemented options---------------------------------------------------
 foreach(opt afs clarens glite pch peac sapdb srp geocad)
   if(${opt})